111 lines
3.2 KiB
SQL
111 lines
3.2 KiB
SQL
CREATE OR REPLACE TRIGGER events__
|
|
FOR UPDATE OR INSERT OR DELETE ON events
|
|
COMPOUND TRIGGER
|
|
|
|
in_table_name CONSTANT user_tables.table_name%TYPE := 'EVENTS';
|
|
--
|
|
curr_log_id logs.log_id%TYPE;
|
|
curr_updated_by events.updated_by%TYPE;
|
|
curr_updated_at events.updated_at%TYPE;
|
|
--
|
|
rows_inserted PLS_INTEGER := 0;
|
|
rows_updated PLS_INTEGER := 0;
|
|
rows_deleted PLS_INTEGER := 0;
|
|
--
|
|
last_rowid ROWID;
|
|
|
|
|
|
|
|
BEFORE STATEMENT IS
|
|
BEGIN
|
|
curr_log_id := app.log_trigger(in_table_name);
|
|
curr_updated_by := app.get_user_id();
|
|
curr_updated_at := SYSDATE;
|
|
EXCEPTION
|
|
WHEN app.app_exception THEN
|
|
RAISE;
|
|
WHEN OTHERS THEN
|
|
app.raise_error('TRIGGER_FAILED', in_table_name);
|
|
END BEFORE STATEMENT;
|
|
|
|
|
|
|
|
BEFORE EACH ROW IS
|
|
BEGIN
|
|
IF NOT DELETING THEN
|
|
:NEW.updated_by := curr_updated_by;
|
|
:NEW.updated_at := curr_updated_at;
|
|
--
|
|
:NEW.app_id := COALESCE(:NEW.app_id, app.get_app_id());
|
|
--
|
|
IF UPDATING AND :NEW.event_id != :OLD.event_id THEN
|
|
UPDATE log_events e
|
|
SET e.event_id = :NEW.event_id
|
|
WHERE e.app_id = :OLD.app_id
|
|
AND e.event_id = :OLD.event_id;
|
|
--
|
|
UPDATE mail_subscriptions e
|
|
SET e.event_id = :NEW.event_id
|
|
WHERE e.app_id = :OLD.app_id
|
|
AND e.event_id = :OLD.event_id;
|
|
END IF;
|
|
ELSE
|
|
DELETE FROM log_events e
|
|
WHERE e.app_id = :OLD.app_id
|
|
AND e.event_id = :OLD.event_id;
|
|
--
|
|
DELETE FROM mail_subscriptions e
|
|
WHERE e.app_id = :OLD.app_id
|
|
AND e.event_id = :OLD.event_id;
|
|
END IF;
|
|
EXCEPTION
|
|
WHEN app.app_exception THEN
|
|
RAISE;
|
|
WHEN OTHERS THEN
|
|
app.raise_error('TRIGGER_FAILED', in_table_name);
|
|
END BEFORE EACH ROW;
|
|
|
|
|
|
|
|
AFTER EACH ROW IS
|
|
new_json VARCHAR2(32767);
|
|
old_json VARCHAR2(32767);
|
|
BEGIN
|
|
IF INSERTING THEN
|
|
rows_inserted := rows_inserted + 1;
|
|
last_rowid := :NEW.ROWID;
|
|
ELSIF UPDATING THEN
|
|
rows_updated := rows_updated + 1;
|
|
last_rowid := :OLD.ROWID;
|
|
ELSIF DELETING THEN
|
|
rows_deleted := rows_deleted + 1;
|
|
last_rowid := :OLD.ROWID;
|
|
END IF;
|
|
EXCEPTION
|
|
WHEN app.app_exception THEN
|
|
RAISE;
|
|
WHEN OTHERS THEN
|
|
app.raise_error('TRIGGER_FAILED', in_table_name);
|
|
END AFTER EACH ROW;
|
|
|
|
|
|
|
|
AFTER STATEMENT IS
|
|
BEGIN
|
|
app.log_success (
|
|
in_log_id => curr_log_id,
|
|
in_rows_inserted => rows_inserted,
|
|
in_rows_updated => rows_updated,
|
|
in_rows_deleted => rows_deleted,
|
|
in_last_rowid => last_rowid
|
|
);
|
|
EXCEPTION
|
|
WHEN app.app_exception THEN
|
|
RAISE;
|
|
WHEN OTHERS THEN
|
|
app.raise_error('TRIGGER_FAILED', in_table_name);
|
|
END AFTER STATEMENT;
|
|
|
|
END;
|
|
/
|