From cd897571d5945d7f7183a9d5beac269716b2b489 Mon Sep 17 00:00:00 2001
From: Jan Kvetina <jan.kvetina@gmail.com>
Date: Thu, 30 Dec 2021 18:57:48 +0100
Subject: [PATCH] Delete related settings

---
 triggers/setting_contexts__.sql | 96 +++++++++++++++++++++++++++++++++
 1 file changed, 96 insertions(+)
 create mode 100644 triggers/setting_contexts__.sql

diff --git a/triggers/setting_contexts__.sql b/triggers/setting_contexts__.sql
new file mode 100644
index 0000000..ddcd838
--- /dev/null
+++ b/triggers/setting_contexts__.sql
@@ -0,0 +1,96 @@
+CREATE OR REPLACE TRIGGER setting_contexts__
+FOR UPDATE OR INSERT OR DELETE ON setting_contexts
+COMPOUND TRIGGER
+
+    in_table_name           CONSTANT user_tables.table_name%TYPE := 'SETTING_CONTEXTS';
+    --
+    curr_log_id             logs.log_id%TYPE;
+    curr_event_id           log_events.log_id%TYPE;
+    curr_updated_by         setting_contexts.updated_by%TYPE;
+    curr_updated_at         setting_contexts.updated_at%TYPE;
+    --
+    rows_inserted           PLS_INTEGER := 0;
+    rows_updated            PLS_INTEGER := 0;
+    rows_deleted            PLS_INTEGER := 0;
+    --
+    last_rowid              ROWID;
+
+
+
+    BEFORE STATEMENT IS
+    BEGIN
+        curr_log_id         := app.log_trigger(in_table_name);
+        curr_updated_by     := app.get_user_id();
+        curr_updated_at     := SYSDATE;
+    EXCEPTION
+    WHEN app.app_exception THEN
+        RAISE;
+    WHEN OTHERS THEN
+        app.raise_error('TRIGGER_FAILED', in_table_name);
+    END BEFORE STATEMENT;
+
+
+
+    BEFORE EACH ROW IS
+    BEGIN
+        IF NOT DELETING THEN
+            :NEW.updated_by := curr_updated_by;
+            :NEW.updated_at := curr_updated_at;
+        ELSE
+            -- delete related rows
+            DELETE FROM settings s
+            WHERE s.app_id              = :OLD.app_id
+                AND s.setting_context   = :OLD.context_id;
+        END IF;
+        --
+        curr_event_id := app.log_event('SETTING_CONTEXTS_CHANGED');
+    EXCEPTION
+    WHEN app.app_exception THEN
+        RAISE;
+    WHEN OTHERS THEN
+        app.raise_error('TRIGGER_FAILED', in_table_name);
+    END BEFORE EACH ROW;
+
+
+
+    AFTER EACH ROW IS
+        new_json    VARCHAR2(32767);
+        old_json    VARCHAR2(32767);
+    BEGIN
+        IF INSERTING THEN
+            rows_inserted       := rows_inserted + 1;
+            last_rowid          := :NEW.ROWID;
+        ELSIF UPDATING THEN
+            rows_updated        := rows_updated + 1;
+            last_rowid          := :OLD.ROWID;
+        ELSIF DELETING THEN
+            rows_deleted        := rows_deleted + 1;
+            last_rowid          := :OLD.ROWID;
+        END IF;
+    EXCEPTION
+    WHEN app.app_exception THEN
+        RAISE;
+    WHEN OTHERS THEN
+        app.raise_error('TRIGGER_FAILED', in_table_name);
+    END AFTER EACH ROW;
+
+
+
+    AFTER STATEMENT IS
+    BEGIN
+        app.log_success (
+            in_log_id               => curr_log_id,
+            in_rows_inserted        => rows_inserted,
+            in_rows_updated         => rows_updated,
+            in_rows_deleted         => rows_deleted,
+            in_last_rowid           => last_rowid
+        );
+    EXCEPTION
+    WHEN app.app_exception THEN
+        RAISE;
+    WHEN OTHERS THEN
+        app.raise_error('TRIGGER_FAILED', in_table_name);
+    END AFTER STATEMENT;
+
+END;
+/